Arduino Nano HV Rescue Shield

/**
   Copyright 2025 Achim Pieters | StudioPieters®

   Permission is hereby granted, free of charge, to any person obtaining a copy
   of this  software and associated documentation files (the "Software"), to deal
   in the Software without restriction, including without limitation the rights
   to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   copies of the Software, and to permit persons to whom the Software is
   furnished to do so, subject to the following conditions:

   The above copyright notice and this permission notice shall be included in all
   copies or substantial portions of the Software.

   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
   FITNESS FOR A PARTICULAR PURPOSE AND NON INFRINGEMENT. IN NO EVENT SHALL THE
   AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
   CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

   for more information visit https://www.studiopieters.nl
 **/

// AVR High-voltage Serial Programmer trough Nano→ATtiny85
// Writes LFUSE=0x62 and HFUSE=0xDF. EFUSE is read only. Baud: 9600.
//
// Nano → ATtiny85 DIP-8:
// D9  → SDI  (pin 5)
// D10 → SII  (pin 6)
// D11 → SDO  (pin 7)
// D12 → SCI  (pin 2)
// D13 → 12V switch → RESET (pin 1)
// 5V → VCC (pin 8), GND → GND (pin 4)

#define HFUSE 0xDF
#define LFUSE 0x62

#define HV_RESET_CTRL 8
#define PIN_SCI       12
#define PIN_SDO       11
#define PIN_SII       10
#define PIN_SDI        9

#define HV_ACTIVE_LOW 1 // HIGH = 12V off, LOW = 12V on (typical NPN transistor setup)

int inByte = 0;
int inData = 0;

void setup() {
  pinMode(HV_RESET_CTRL, OUTPUT);
  pinMode(PIN_SDI, OUTPUT);
  pinMode(PIN_SII, OUTPUT);
  pinMode(PIN_SCI, OUTPUT);
  pinMode(PIN_SDO, OUTPUT);

#if HV_ACTIVE_LOW
  digitalWrite(HV_RESET_CTRL, HIGH); // 12V off
#else
  digitalWrite(HV_RESET_CTRL, LOW);
#endif

  Serial.begin(9600);
  establishContact();
}

void loop() {
  if (Serial.available() > 0) {
    inByte = Serial.read();
    Serial.println();
    Serial.println(F("Entering programming Mode"));

    pinMode(PIN_SDO, OUTPUT);
    digitalWrite(PIN_SDI, LOW);
    digitalWrite(PIN_SII, LOW);

#if HV_ACTIVE_LOW
    digitalWrite(HV_RESET_CTRL, HIGH);
#else
    digitalWrite(HV_RESET_CTRL, LOW);
#endif

    delayMicroseconds(20);

#if HV_ACTIVE_LOW
    digitalWrite(HV_RESET_CTRL, LOW);  // 12V on
#else
    digitalWrite(HV_RESET_CTRL, HIGH); // 12V on
#endif
    delayMicroseconds(10);

    pinMode(PIN_SDO, INPUT);
    delayMicroseconds(300);

    readFuses();

    Serial.println(F("Writing hfuse"));
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x40, 0x4C);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, HFUSE, 0x2C);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x74);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x7C);

    Serial.println(F("Writing lfuse"));
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x40, 0x4C);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, LFUSE, 0x2C);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x64);
    shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x6C);

    readFuses();

    Serial.println(F("Exiting programming Mode"));
    Serial.println();

#if HV_ACTIVE_LOW
    digitalWrite(HV_RESET_CTRL, HIGH); // 12V off
#else
    digitalWrite(HV_RESET_CTRL, LOW);
#endif
  }
}

void establishContact() {
  while (Serial.available() <= 0) {
    Serial.println(F("Enter a character to continue"));
    delay(800);
  }
}

int shiftOut2(uint8_t dataPin, uint8_t instPin, uint8_t clockPin,
              uint8_t bitOrder, byte valData, byte valInst) {
  int inBits = 0;

  while (!digitalRead(PIN_SDO));

  digitalWrite(PIN_SDI, LOW);
  digitalWrite(PIN_SII, LOW);
  digitalWrite(clockPin, HIGH);
  digitalWrite(clockPin, LOW);

  for (int i = 0; i < 8; i++) {
    if (bitOrder == LSBFIRST) {
      digitalWrite(dataPin,  !!(valData & (1 << i)));
      digitalWrite(instPin,  !!(valInst & (1 << i)));
    } else {
      digitalWrite(dataPin,  !!(valData & (1 << (7 - i))));
      digitalWrite(instPin,  !!(valInst & (1 << (7 - i))));
    }
    inBits <<= 1;
    inBits |= digitalRead(PIN_SDO);
    digitalWrite(clockPin, HIGH);
    digitalWrite(clockPin, LOW);
  }

  digitalWrite(PIN_SDI, LOW);
  digitalWrite(PIN_SII, LOW);
  digitalWrite(clockPin, HIGH);
  digitalWrite(clockPin, LOW);
  digitalWrite(clockPin, HIGH);
  digitalWrite(clockPin, LOW);

  return inBits;
}

void readFuses() {
  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x04, 0x4C);
  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x68);
  inData = shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x6C);
  Serial.print(F("lfuse reads as "));
  Serial.println(inData, HEX);

  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x04, 0x4C);
  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x7A);
  inData = shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x7E);
  Serial.print(F("hfuse reads as "));
  Serial.println(inData, HEX);

  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x04, 0x4C);
  shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x6A);
  inData = shiftOut2(PIN_SDI, PIN_SII, PIN_SCI, MSBFIRST, 0x00, 0x6E);
  Serial.print(F("efuse reads as "));
  Serial.println(inData, HEX);
  Serial.println();
}